system/virtualization: init from legacy

legacy/modules/kvm.nix

@@ -1,13 +0,0 @@
-{ config, lib, pkgs, ... }:
-
-{
-  boot.kernelModules = [
-    "kvm-amd"
-    "kvm-intel"
-  ];
-  virtualisation.libvirtd.enable = true;
-
-  environment.systemPackages = with pkgs; [
-    virtmanager
-  ];
-}

machines/thinkman/configuration.nix

@@ -14,7 +14,6 @@
     ../../legacy/modules/gaming.nix
     ../../legacy/modules/hardware-base.nix
     ../../legacy/modules/intel-video.nix
-    ../../legacy/modules/kvm.nix
     ../../legacy/modules/location.nix
     ../../legacy/modules/media.nix
     ../../legacy/modules/meeting.nix

machines/thinkman/system.nix

@@ -7,5 +7,9 @@ in
   my.system = {
     avahi.enable = true;
     podman.enable = true;
+    virtualization = {
+      enable = true;
+      cpuFlavor = "intel";
+    };
   };
 }

modules/system/default.nix

@@ -4,6 +4,7 @@
     ./avahi
     ./docker
     ./podman
+    ./virtualization
   ];
 }
 

modules/system/virtualization/default.nix

@@ -0,0 +1,40 @@
+{ config, lib, pkgs, ... }:
+let
+  cfg = config.my.system.virtualization;
+in
+{
+  options.my.system.virtualization = with lib; {
+    enable = mkEnableOption "virtualization configuration";
+
+    cpuFlavor = mkOption {
+      type = with types; nullOr (enum [ "intel" "amd" ]);
+      default = null;
+      example = "intel";
+      description = "Which kind of CPU to activate kernelModules";
+    };
+  };
+
+  config = lib.mkIf cfg.enable (lib.mkMerge [
+    {
+      virtualisation.libvirtd.enable = true;
+
+      environment.systemPackages = with pkgs; [
+        virtmanager
+      ];
+    }
+
+    # Intel CPU
+    (lib.mkIf (cfg.cpuFlavor == "intel") {
+      boot.kernelModules = [
+        "kvm-intel"
+      ];
+    })
+
+    # AMD CPU
+    (lib.mkIf (cfg.cpuFlavor == "amd") {
+      boot.kernelModules = [
+        "kvm-amd"
+      ];
+    })
+  ]);
+}